Cuando se Fisher z-transformar la adecuada?

Question

Quiero hacer una prueba de correlación de $r$ de significación, utilizando los valores de p, que es

$H_0: \rho = 0, \; H_1: \rho \neq 0.$

Tengo entendido que puedo usar de Fisher z-transformación para el cálculo de este por

$z_{obs}= \displaystyle\frac{\sqrt{n-3}}{2}\ln\left(\displaystyle\frac{1+r}{1-r}\right)$

y encontrar el valor de p por

$p = 2P\left(Z>z_{obs}\right)$

el uso de la distribución normal estándar.

Mi pregunta es: ¿qué tan grande $n$ debe ser para que esto sea una transformación apropiada? Obviamente, $n$ debe ser mayor que 3. Mi libro de texto no menciona ningún tipo de restricciones, pero en la diapositiva 29 de esta presentación se dice que $n$ debe ser mayor que 10. Para los datos que se esté considerando, voy a tener algo como $5 \leq n \leq 10$.

Answer 1

Para preguntas como estas acabo de ejecutar una simulación y ver si el $p$-valores se comportan como espero que ellos. El $p$-valor es la probabilidad de dibujo al azar una muestra de que se desvía al menos tanto desde el contraste de hipótesis que los datos que se observa si el contraste de hipótesis es verdadera. Así que si hemos tenido muchas de esas muestras, y uno de ellos tenía un $p$-valor de .04 entonces sería de esperar 4% de las muestras que tienen un valor menor .04. Lo mismo es cierto para el resto de posibles $p$-valores.

Por debajo es una simulación en el programa Stata. Los gráficos comprobar si el $p$-valores de medición de lo que se supone que debe medir, es decir, que muestra lo mucho que la proporción de muestras con $p$-valores inferiores a la nominal $p$-valor difiere de la nominal $p$-valor. Como se puede ver que la prueba es algo problemático con reducido número de observaciones. Si es o no es demasiado problemático para su investigación es de su juicio.

clear all
set more off

program define sim, rclass
    tempname z se
    foreach i of numlist 5/10 20(10)50 {
        drop _all
        set obs `i'
        gen x = rnormal()
        gen y = rnormal()
        corr x y 
        scalar `z'  = atanh(r(rho))
        scalar `se' = 1/sqrt(r(N)-3)
        return scalar p`i' = 2*normal(-abs(`z'/`se'))
    }
end

simulate p5 =r(p5)  p6 =r(p6)  p7  =r(p7)     ///
         p8 =r(p8)  p9 =r(p9)  p10 =r(p10)    ///
         p20=r(p20) p30=r(p30) p40 =r(p40)    ///
         p50=r(p50), reps(200000) nodots: sim 

simpplot p5 p6 p7 p8 p9 p10, name(small, replace) ///
    scheme(s2color) ylabel(,angle(horizontal)) 

simpplot p20 p30 p40 p50 , name(less_small, replace) ///
    scheme(s2color) ylabel(,angle(horizontal)) 

Answer 2

No está seguro de si un Fisher $z$ transformar es apropiado aquí. Para $H_0: \rho=0$ (NB: la hipótesis nula es que la población $\rho$, no muestra $r$), la distribución muestral del coeficiente de correlación ya es simétrico, por lo que no hay necesidad de reducir la asimetría, que es lo que Fisher $z$ pretende hacer, y usted puede utilizar Estudiante $t$ aproximación.

Suponiendo que te refieres a $H_0: \rho = \rho_0 \not = 0$, entonces la asimetría de ese PDF dependerá de la propuesta de valor de $\rho_0$, por lo que habría entonces no hay una respuesta general de cómo un gran $n$ debe ser. También, los valores mínimos de $n$ dependería del nivel de significación $\alpha$ que están trabajando. Usted no ha estado de su valor.

Nick punto es justa: las aproximaciones y las recomendaciones están siempre en funcionamiento en algunos de la zona gris.

Si, entonces, su Fisher aproximación es buena (=simétrica) suficiente, me gustaría utilizar el enlazado $n\geq (t_{\alpha/2} s/\epsilon)^2$ aplicable a la $t$-distribuciones, donde $s$ es la desviación estándar de la muestra. Si está lo suficientemente cerca a la normalidad, esto se convierte en $n \geq (1.96 s/\epsilon)^2$.