$\lim_{n\to\infty} f(2^n)$ muy lentamente creciente función $f(n)$

Question

Yo debería ser capaz de responder a mí mismo, pero se sienten inseguros de todos modos. Quiero saber, si una función f(n) está acotada si n tiende a infinito (y si es acotado, el límite). De forma heurística parece (y supongo que para la generalidad) que f(n) es monotonuously en aumento. Pero el incremento de f(n) para n=1,2,3,4,... diminuishes y si finalmente converge, entonces la convergencia es demasiado lenta para la estimación de algún límite.
Así que me veo en la secuencia de f(2^n) y encontrar, que el aumento de la (="$\Delta(n)$") parece reducir a la mitad en cada paso. Aquí está la tabla de valores.

$ \pequeño \begin{array} {cccc} 2^n & f(2^n)& \Delta(n) =f(2^n)-f(2^n/2) & Q(n)=\Delta(n+1)/\Delta(n) \\ 2 & 1.00000000000 & 1.00000000000 & 1.00000000000 \\ 4 & 1.20710678119 & 0.207106781187 & 0.207106781187 \\ 8 & 1.32489552200 & 0.117788740818 & 0.568734351153 \\ 16 & 1.38378655210 & 0.0588910300981 & 0.499971641511 \\ 32 & 1.41323838275 & 0.0294518306501 & 0.500107242156 \\ 64 & 1.42796608046 & 0.0147276977050 & 0.500060518479 \\ 128 & 1.43533039941 & 0.00736431894937 & 0.500031919236 \\ 256 & 1.43901267941 & 0.00368228000046 & 0.500016366181 \\ 512 & 1.44085384991 & 0.00184117050297 & 0.500008283655 \\ 1024 & 1.44177444283 & 0.000920592923335 & 0.500004166833 \\ 2048 & 1.44223474122 & 0.000460298385385 & 0.500002089651 \\ 4096 & 1.44246489089 & 0.000230149674341 & 0.500001046382 \\ 8192 & 1.44257996585 & 0.000115074957672 & 0.500000523580 \end{array} $

Como P(n) tiende a 0.5, creo que debería concluir que f(n) está acotada porque la suma de todos los $\Delta$ es acotado, pero siento que no estoy seguro de si esta es una conclusión significativa aquí.
Y si fueron significativos: lo que luego sería una estimación razonable para el límite superior?

---

[actualización]: Heurísticas sugieren, que $$ f(n) \approx { {n-1 \over \log(2)} + {1 \over 2} \over n} $$ and then $$\lim_{n \to \infty} f(n) = {1 \over \log(2)} \approx 1.44269504089 $$
[actualización]

---

Los resultados de la función de una adaptación de el problema, si por algún exponente del número entero n la suma de los n-esima potencia de la primera m números iguales (m+1)^n, que diga si existen algunas natural n>2, m>2, tal que $S(m,n) = (m+1)^n $ donde $S(m,n)=\sum_{k=1}^m k^n $ .

Puedo convertir esto en una formulación mediante el bernoulli-polinomios para la suma de los n-ésimos poderes. No es difícil de encontrar, que m debe ser mayor que n.
Por el uso de los bernoulli-polinomios uno puede también de manera significativa interpolar m fraccional de valores, digamos x, en la suma de S(m,n). De manera que d(x,n) es la diferencia de $d(x,n) = B(x,n)- (x+1)^n$ donde B(x,n) es la de Bernoulli-polinomio de forma generalizada de S(m,n).

Con esto, para un entero dado n, voy a resolver para x tal que d(x,n)=0. De nuevo, en general x>n, pero quiero saber, si x/n es limitada... Así que determinan $f(n)={\text{<root x of d(x,n)>} \over n} $
Comentario: en mi anterior notación arriba en la tabla I x donde me refería a que el exponente que yo ahora de manera más significativa denota como n.

---

Así, mientras estoy escribiendo esto: posiblemente el actual problema puede ser resuelto de una manera mucho más sencilla.... (Al menos ahora he significativo heurística, ver arriba)

Pero mi más profunda curiosidad es acerca de la idea; si-y en qué medida - la idea de "aceleración de la convergencia" es/puede ser valida para este tipo de conclusión?

Answer 1

Esto es más de un (numérico) la plausibilidad de argumento para apoyar Gottfried $\lim\limits_{n \to \infty} f(n) = \frac1{\log\;2}$ conjetura de que una respuesta.

Lo que me llamó la atención fue que el error de proporciones $Q(n)$ $n$ se duplica parecen indicar una disminución en el error por un factor de 2. Esto me recordó de la disminución en el error exhibido por la regla trapezoidal para la integración numérica como el número de subintervalos se duplica, lo que me llevó a pensar que la extrapolación de Richardson podría ser adecuado para su uso en aproximar numéricamente el límite, igual que la forma en la extrapolación de Richardson se utiliza para mejorar trapezoidal estimaciones en Romberg cuadratura.

Recordemos que lo que la extrapolación de Richardson, esencialmente, no es para que se ajuste a un polinomio de interpolación de $p(x)$ a los sucesivos valores de una secuencia $s_i$, junto con algunos auxiliares secuencia $x_i$ que tiende a 0 $i\to\infty$ tal que $p(x_i)=s_i$, y, a continuación, tome $p(0)$ a la estimación del límite de la secuencia de $s_i$. Para este caso en particular, la proporción de error que aparecen al enfoque 2 sugiere que tomamos el auxiliar secuencia $x_j=2^{-j}$.

El Richardson esquema procede de la siguiente manera: dejando $T_j^{(0)}=s_j$, se genera un arreglo triangular de valores

$$\begin{matrix}T_0^{(0)}&&&&\\T_1^{(0)}&T_1^{(1)}&&&\\T_2^{(0)}&T_2^{(1)}&T_2^{(2)}&&\\\vdots&\vdots&\vdots&\ddots&\\T_n^{(0)}&T_n^{(1)}&\cdots&\cdots&T_n^{(n)}\end{matrix}$$

whose entries are generated according to the recursive formula

$$T_j^{(n)}=T_{j}^{(n-1)}+\frac{T_{j}^{(n-1)}-T_{j-1}^{(n-1)}}{\frac{x_{j-n}}{x_j}-1}$$

and the $T_n^{(n)}$ (i.e., the "diagonal" elements of the array) form a sequence which (hopefully) converges faster to the limit than the original $s_j$. For this specific example, we have $s_j=f(2^{j+1})$ and $\frac{x_{j-n}}{x_j}=2^n$.

The Richardson scheme can be implemented such that only a one-dimensional array is needed, and this is what I will do in the Mathematica code that follows (specializing to the case $\frac{x_{j-n}}{x_j}=2^n$):

richardson[seq_?VectorQ] := Module[{n = Length[seq], m, res, ta},
  ta[1] = First[seq]; res = {First[seq]};
  Do[
   ta[k + 1] = seq[[k + 1]];
   m = 1;
   Do[
    m *= 2;
    ta[j] = ta[j + 1] + (ta[j + 1] - ta[j])/(m - 1);
    , {j, k, 1, -1}];
   res = {res, ta[1]};
   , {k, n - 1}];
  Flatten[res]
  ]

We then generate the (first fourteen members of the) sequence in the OP to 100 significant figures:

pa[n_Integer, x_] := Expand[Sum[(-1)^k*BernoulliB[k]*Binomial[n, k]*
   (x^(n - k + 1)/(n - k + 1)),
   {k, n}] +  x^(n + 1)/(n + 1) - (x + 1)^n]

vals = Table[x/2^j /. FindRoot[pa[2^j - 1, x] == 0, {x, 2^j - 1, 2^(j + 1) - 2}, 
    WorkingPrecision -> 100], {j, 14}];

Last[vals] (* sample value, j == 14 *)
1.442637503359895400534264282420018712540776326004454785114823591142583865448308469439211266125019043

If we apply richardson[] to vals, we get the following:

Last[richardson[vals]]
1.44269504088896340735992467998804478392151992973760702424401781700078935678750451268434910460102062

% - 1/Log[2]
-1.0138473535051260244153789098914315899303198623936805672011775182924857213751333727278493`*^-27

and the result of the extrapolation matches $\frac1{\log\;2}$ to ~ 27 digits.

Generating more members of the sequence and computing with more digits might give a more accurate value, but instead of doing this, I decided to apply a different extrapolation algorithm, the Shanks transformation, with the reasoning that if two unrelated algorithms give (almost) the same answer for a given sequence, the answer is likely correct.

I will skip the details of the mathematics behind the Shanks transformation (but see this article) and instead present Mathematica code:

wynnEpsilon[seq_?VectorQ] := Module[{n = Length[seq], ep, res, v, w},
  res = {};
  Do[
   ep[k] = seq[[k]];
   w = 0;
   Do[
    v = w; w = ep[j];
    ep[j] = 
     v + (If[Abs[ep[j + 1] - w] > 10^-(Precision[w]), ep[j + 1] - w, 
         10^-(Precision[w])])^-1;
    , {j, k - 1, 1, -1}];
   res = {res, ep[If[OddQ[k], 1, 2]]};
   , {k, n}];
  Flatten[res]
  ]

This is essentially the algorithm behind the hidden built-in Mathematica function SequenceLimit[], but I have chosen to implement the algorithm explicitly for pedagogical reasons.

We then have the results

Last[wynnEpsilon[vals]]
1.442695040888963407376933999717472189155804331509810458775727421372220122967729979363328849794520

% - 1/Log[2]
1.70093187155800517291583773568245246402780144411109037865448994778022269010133063583652`*^-20

with a result that matches $\frac1{\log\;2}$ to ~ 20 digits. (The slight loss of accuracy is the price for the generality of the Shanks transformation, which did not exploit the behavior of the error ratios.)

The results of these two different extrapolation algorithms lends credibility to the conjecture that the limit is $\frac1{\log\;2}$.

Answer 2

Concebible, es la función $f(x)$ $0.00005$ $1.44$ hasta $x + 2^{2^{2^{10}}}$de %, pero sólo entonces se dispararían repentinamente la función. Saber localizados datos no nos dice nada sobre los límites de la función sin algún otro tipo de conocimiento, como la forma de la función, las características de su variación o derivado, etcetera.

Answer 3

Esta no es una respuesta, pero Pari/GP-código para el cálculo de los datos de acuerdo a J. M. del comentario.
Para el cálculo de punto flotante yo uso interno de precisión de 200 dic dígitos por defecto.

\\ ==================== Pari/GP-Code =========================================
\\ Bernoulli-polynomials (in the Faulhaber-form, expressed in terms of zeta)  
\\           keep exponent in global variable bn
{ init_bp(n) = bn = n;            \\ set global variable bn for exponent
          bp = vector(2+n);       \\ coefficients of bernoulli-polynomial in global variable bp
            bp[1+0] = 0;          \\ remember: Pari/GP indexes begin with offset 1
            for(c = 1, n, bp[1+c] = -zeta(c-n) * binomial(n,c)) ;
            bp[1+(1+n)] = 1/(1+n); 
          return(bp); }

\\ sum-of-like-powers 1^n + 2^n +... + x^n
\\     by bernoulli-polynomials
solp(x) = return( sum(k = 0, #bp -1, x^k * bp[1+k] )  ) 

\\ difference-function   (1^n+2^n+...+x^n) - (x+1)^n
solp_d(x)= solp(x) - (x+1)^bn       


\\ final criterion-function : find root for some solp_d(n)
\\ solp_d(n)/(n+1)
{ f(n) = init_bp(n); 
       x0 = solve(x = bn, 2*bn, solp_d(x) ) ;   \\ find root between n and 2n
       return( x0 /(bn+1) ); }



\\ -----------------------------------------------------
\\ remark: in the documented data of my question I had an additional
\\ index-offset of 1, so the data for displayed exponent n=8 were
\\ really for n=7
\\ so disp_f(512) gives the same value as documented for 512
disp_f(n) = f(n-1)

disp_f(128) \\ should be 1.43533039941

\\ -----------------------------------
delta(n)= if(n==1, disp_f(2^n), disp_f(2^n)-disp_f(2^n/2))

delta(2)  \\ should be 0.207106781187


\\ -----------------------------------
q(n) = if(n==1, 1, delta(n)/delta(n-1))

q(3) \\ should be 0.568734351153