Lo que se espera que la distribución de los residuos en un modelo lineal generalizado?

Question

Estoy realizando un modelo lineal generalizado, donde tengo que especificar una familia diferente de la normal.

• Lo que se espera que la distribución de los residuos?
• Por ejemplo, en caso de que los residuos se distribuyen normalmente?

Answer 1

Hay toda una industria artesanal se centra en torno a diseño de residuos de la GLMs que son más simétricos o incluso aproximadamente "normal" (es decir, de Gauss), por ejemplo, Pearson resiudals, Anscombe residuos, (ajustada) de la desviación de los residuos, etc. Véase, por ejemplo, el Capítulo 6 de James W. Hardin y José M. Hilbe (2007) "Modelos Lineales Generalizados y Extensiones", segunda edición. College Station, TX: Stata Press. Si la variable dependiente es discreta (un indicador o una variable de recuento), entonces es obviamente muy duro para hacer que la distribución esperada de los residuos exactamente Gaussiano.

Una cosa que puedes hacer es repetidamente simular nuevos datos bajo la suposición de que su modelo es cierto, la estimación de su modelo con el que los datos simulados y calcular los residuos, y de comparar su actual resiudals con su simulada de los residuos. En Stata yo lo haría de esta manera:

sysuse nlsw88, clear
glm wage i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)

// collect which observations were used in estimation and the predicted mean
gen byte touse = e(sample)
predict double mu if touse

// predict residuals
predict resid if touse, anscombe

// prepare variables for plotting a cumulative distribution function
cumul resid, gen(c)

// collect the graph command in the local macro `graph'
local graph "twoway"

// create 19 simulations:
gen ysim = .
forvalues i = 1/19 {
    replace ysim = rpoisson(mu) if touse
    glm ysim i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)
    predict resid`i' if touse, anscombe
    cumul resid`i', gen(c`i')
    local graph "`graph' line c`i' resid`i', sort lpattern(solid) lcolor(gs8) ||"
}
local graph "`graph' line c resid, sort lpattern(solid) lcolor(black) "

// display the graph
`graph' legend(order(20 "actual residuals" 1 "simulations")) 

Answer 2

What is the expected distribution of residuals?

Varía con el modelo de las maneras que hacen esto imposible responder en general.

For example, should the residuals be distributed normally?

Generalmente no, no.