¿Es el área de un pentágono inscrito en una elipse independiente del punto de partida?

Question

Dada una elipse, si eliges 5 puntos de la elipse que estén separados por una longitud de arco igual, ¿el pentágono formado por estos puntos tiene la misma área independientemente de la posición inicial?

Si es así, ¿cómo se podría probar que esto es o no es el caso?

Por lo tanto, se ha demostrado que la conjetura es errónea, pero sigue habiendo casos especiales de la elipse 3:4 en los que la conjetura parece mantenerse.

Este problema surgió de esta discusión en brilliant.org.

Answer 1

Creo que esto no es cierto. Para un $(3,4)$ pentágono empezando por el final del eje mayor, obtengo un área de 28,4032, y en el eje menor obtengo 28,4020.

Obviamente, se trata de una diferencia muy pequeña; trataré de justificar la afirmación de que no se trata de un error de redondeo. He realizado mis cálculos más internos con WorkingPrecision ajustado a 100 dígitos. Para comprobar mis cálculos, recorrí directamente cada uno de los 5 arcos alrededor de la elipse, en lugar de fijar manualmente el vértice final igual al inicial; la diferencia entre el vértice inicial y la posición calculada para el final fue del orden de $10^{-12}$ .

En cuanto a la parametrización $(a \sin \theta, b \cos \theta)$ me sale que los vértices están en $\theta$ valores de

{0.000000000000, 1.292954985206, 2.443082328571, 3.840102978604, 4.990230321969, 6.283185307175}
{1.570796326795, 2.779128093468, 4.147204875501, 5.277573085264, 6.645649867296, 7.853981633971}

Obsérvese que la última entrada de cada fila es casi $2 \pi$ y $5 \pi/2$ respectivamente, pero difiere en el último dígito dado; si el cálculo fuera exacto, serían exactamente iguales.

---

Permítanme también dar una explicación intuitiva de por qué esperamos que la variación sea pequeña. Sea la parametrización de la longitud del arco $(a \sin \theta(t), b \cos \theta(t))$ . Entonces $\theta'(t)$ es proporcional a $1/\sqrt{a^2 \cos^2 \theta(t) + b^2 \sin^2(t)}$ que sólo varía entre $1/a$ y $1/b$ . No está tan lejos de sólo tomar $\theta$ varíe linealmente con $t$ . Por ejemplo, si $(a,b)=(3,4)$ y se conduce alrededor de una pista elíptica a un ritmo constante de $\theta'$ Entonces su velocidad mínima y máxima están en una proporción de 3/4, como el cambio entre 60 MPH y 80 MPH. Se nota, pero no es gigante.

Si conducimos a un ritmo constante $\theta'$ Entonces el área no depende del punto de partida. Para ver esto, observa que el pentágono con vértices en $(a \cos(\theta_0 + 2 \pi k/5), b \sin(\theta_0 + 2 \pi k/5))$ es la imagen bajo el mapa lineal $(x,y) \mapsto (ax,by)$ de un pentágono regular. El área del pentágono regular es independiente de $\theta_0$ y los mapas lineales conservan las proporciones de las áreas.

Cuando manejamos la parametrización de la longitud de arco en lugar de la constante $\theta'$ En este caso, ya no estamos considerando imágenes lineales de pentágonos regulares, sino de pentágonos que se acercan a los regulares. Me ha sorprendido lo cerca que están: Empezando por el final del eje menor, descubrí que tengo que ir a $\theta = 2 \pi \cdot 0.20578$ para conseguir $1/5$ de la vuelta; empezando por el eje mayor, necesitaba $\theta = 2 \pi \cdot 0.18794$ Así que sólo hay un 10% de diferencia. Además, las discrepancias de la regularidad empujan en ambos sentidos, con algunos bordes que se alargan y otros que se acortan, por lo que el cambio de área total es aún menor.

Para ser sincero, me sigue sorprendiendo lo pequeña que es la variación. Me encantaría ver una respuesta que calculara aproximadamente cuánta variación cabe esperar para una elipse en función de su excentricidad.

---

Mathematica el código es el siguiente:

(* Minor and major axis, and the total perimeter computed once and for all. *)

a = 3; b = 4; perimeter = NIntegrate[Sqrt[a^2 Cos[t]^2 + b^2 Sin[t]^2], {t, 0, 2 Pi}, WorkingPrecision -> 100]

(* If you are at position theta, and want to move a fraction delta
   around the ellipse, what angle should you go to? 
   Because of the branch cut in EllipticE, delta must be between 0 and 1/2. *)

forward[theta_, delta_] :=
Re[phi] /. 
  FindRoot[
    Integrate[Sqrt[a^2 Cos[t]^2 + b^2 Sin[t]^2], {t, theta, phi}, 
                Assumptions -> theta < phi < theta + Pi] == delta*perimeter, 
    {phi, 2 Pi*delta}, WorkingPrecision -> 100]

eParam[theta_] := {a Sin[theta], b Cos[theta]}

(* Find the vertices of an equal arc n-gon, starting at theta=t0. *)

ePolygon[t0_, n_] := eParam /@ NestList[forward[#, 1/n] &, t0, n]

(* Computes the area of a convex polygon, given a list of vertices. *)

area[L_] := (1/2) Abs[Sum[Det[{L[[i]], L[[i + 1]]}], {i, 1, Length[L] - 1}]]