¿Qué prueba estadística utiliza -contraste- después de la regresión en Stata?

Question

Estoy utilizando el comando -contrast- para generar valores p para la prueba de tendencia en Stata. He revisado la documentación sobre el contraste, pero no encuentro información sobre qué prueba estadística se está utilizando entre bastidores y, por lo tanto, cómo interpretar los valores p asociados a la prueba lineal frente a la cuadrática frente a la conjunta.

Antecedentes de mi código: el resultado de mi modelo es no_dm_dmg_v2 y mi exposición es mtdnaquint que son los quintiles de un biomarcador y la entrada como indicador ( i. ) con la referencia Q5 (b5).

logistic no_dm_dmg_v2 ib5.mtdnaquint_new mtdnacnage male black

Salida

Logistic regression                             Number of obs     =      9,124
                                                LR chi2(7)        =     407.12
                                                Prob > chi2       =     0.0000
Log likelihood = -3550.0948                     Pseudo R2         =     0.0542

------------------------------------------------------------------------------
no_dm_dmg_v2 | Odds Ratio   Std. Err.      z    P>|z|     [95% Conf. Interval]
-------------+----------------------------------------------------------------
  mtdnaquint |
          1  |   .5521241   .0525977    -6.24   0.000     .4580866     .665466
          2  |   .6958681   .0682745    -3.70   0.000     .5741323     .843416
          3  |   .8617032   .0858859    -1.49   0.135     .7087915    1.047604
          4  |   .9143168   .0917151    -0.89   0.372     .7511257    1.112963
             |
  mtdnacnage |    .952226   .0051524    -9.05   0.000     .9421808    .9623783
        male |   .8150846   .0503448    -3.31   0.001     .7221495    .9199798
       black |   .3192515   .0208311   -17.50   0.000     .2809261    .3628054
       _cons |   193.5929    63.4069    16.08   0.000     101.8821    367.8586
------------------------------------------------------------------------------

contrast p.mtdnaquint_new, noeffects

Contrasts of marginal linear predictions

Margins      : asbalanced

------------------------------------------------
             |         df        chi2     P>chi2
-------------+----------------------------------
  mtdnaquint |
   (linear)  |          1       46.41     0.0000
(quadratic)  |          1        2.93     0.0372
    (cubic)  |          1        0.05     0.8261
  (quartic)  |          1        0.30     0.5814
      Joint  |          4       51.46     0.0000
------------------------------------------------

Cuando utilizo la codificación de referencia ( r. ), entiendo que los valores p de cada nivel son ese nivel comparado con la referencia, y son los mismos que los valores p de Wald en la salida de la regresión (ya que he utilizado i.mtdnaquint_new ).

contrast r.mtdnaquint_new, noeffects

Contrasts of marginal linear predictions

Margins      : asbalanced

------------------------------------------------
             |         df        chi2     P>chi2
-------------+----------------------------------
  mtdnaquint |
   (1 vs 5)  |          1       38.88     0.0000
   (2 vs 5)  |          1       13.66     0.0002
   (3 vs 5)  |          1        2.23     0.1353
   (4 vs 5)  |          1        0.80     0.3718
      Joint  |          4       51.46     0.0000
------------------------------------------------

¿Es el valor p conjunto en la salida del contraste r. lo mismo que hacer una prueba de que todas las beta's = 0? ¿Se está probando una tendencia lineal?

Answer 1

Aquí hay ejemplos que muestran esto en Stata para OLS, pero la intuición se traslada a los coeficientes de la función de índice logit.

Ambos están haciendo pruebas de Wald. Hagamos primero la segunda. Usted está probando que la función de índice lineal dentro del logit es la misma para todos los grupos, cada uno con respecto al valor base, por lo que es la misma prueba de que todos los coeficientes son cero (excluyendo la constante). La prueba conjunta de que todas estas diferencias son iguales:

cls
net from http://www.stata-press.com/data/ivrm/
net get ivrm
use "pain.dta", clear
reg pain i.dosegrp
test 2.dosegrp
test 3.dosegrp
test 4.dosegrp
test 5.dosegrp
test 6.dosegrp
test 2.dosegrp 3.dosegrp 4.dosegrp 5.dosegrp 6.dosegrp  

contrast r.dosegrp, noeffects

El contraste polinómico es más complicado. El análisis de la tendencia divide la suma de los cuadrados del modelo en partes debidas a la tendencia lineal, la tendencia cuadrática, la tendencia cúbica, etc. Si hay $K$ grupos, es posible mirar hasta $K - 1$ tendencias. He aquí un ejemplo con $K=6$ con los mismos datos anteriores.

El análisis de tendencias se realiza mediante coeficientes de polinomios ortogonales . Para 6 niveles, se ven como:

             g1  g2  g3  g4 g5   g6
Linear      -5  -3  -1   1   3   5
Quadratic    5  -1  -4  -4  -1   5
Cubic       -5   7   4  -4  -7   5
Quartic      1  -3   2   2  -3   1
Quintic     -1   5 -10  10  -5   1 

Una forma de realizar el análisis de tendencias es utilizar los coeficientes de los polinomios ortogonales para ponderar las sumas de los grupos y calcular las sumas de los cuadrados de cada una de las tendencias. Una alternativa es aplicar los coeficientes de los polinomios ortogonales directamente a las observaciones y analizarlas mediante regresión. Esto crea un conjunto de variables tal que los "efectos" de todas las variables precedentes se han eliminado de cada variable:

net from http://www.stata-press.com/data/ivrm/
net get ivrm
use "pain.dta", clear

/* (1) Automated Polynomial Contrasts */
regress pain i.dosegrp
contrast p.dosegrp, noeffects

/* (2) Slightly More Manual With User-Defined Contrasts on the levels of dosegrp */
contrast {dosegrp -5  -3  -1   1   3   5}  ///
         {dosegrp  5  -1  -4  -4  -1   5}  ///
         {dosegrp -5   7   4  -4  -7   5}  ///
         {dosegrp  1  -3   2   2  -3   1}  ///
         {dosegrp -1   5 -10  10  -5   1}  ///
         {dosegrp -1   5 -10  10  -5   1}, noeffects

/* (3) Regression method where Stata creates the varibles for you */
orthpoly dosegrp, deg(5) generate(op*)
regress pain op*
test op1 // linear
test op2 // quadratic
test op3 // cubic
test op4 // quartic
test op5 // quintic
test op1 op2 op3 op4 op5 // joint

/* (4) Very Manual Way Using Regression Where You Hard Code Everything */
forvalues i=1/5 {
    gen o`i' = .
}

replace o1 = -5 if dosegrp == 1
replace o2 =  5 if dosegrp == 1
replace o3 = -5 if dosegrp == 1
replace o4 =  1 if dosegrp == 1
replace o5 = -1 if dosegrp == 1

replace o1 = -3 if dosegrp == 2
replace o2 = -1 if dosegrp == 2
replace o3 =  7 if dosegrp == 2
replace o4 = -3 if dosegrp == 2
replace o5 =  5 if dosegrp == 2

replace o1 =  -1 if dosegrp == 3
replace o2 =  -4 if dosegrp == 3
replace o3 =   4 if dosegrp == 3
replace o4 =   2 if dosegrp == 3
replace o5 = -10 if dosegrp == 3

replace o1 =  1 if dosegrp == 4
replace o2 = -4 if dosegrp == 4
replace o3 = -4 if dosegrp == 4
replace o4 =  2 if dosegrp == 4
replace o5 = 10 if dosegrp == 4

replace o1 =  3 if dosegrp == 5
replace o2 = -1 if dosegrp == 5
replace o3 = -7 if dosegrp == 5
replace o4 = -3 if dosegrp == 5
replace o5 = -5 if dosegrp == 5

replace o1 = 5 if dosegrp == 6
replace o2 = 5 if dosegrp == 6
replace o3 = 5 if dosegrp == 6
replace o4 = 1 if dosegrp == 6
replace o5 = 1 if dosegrp == 6

tw connected o1 dosegrp, sort
tw connected o2 dosegrp, sort
tw connected o3 dosegrp, sort
tw connected o4 dosegrp, sort
tw connected o5 dosegrp, sort

reg pain o1 o2 o3 o4 o5
test o1 // linear
test o2 // quadratic
test o3 // cubic
test o4 // quartic
test o5 // quintic
test o1 o2 o3 o4 o5 // joint