Diferencia de simulación entre dos OpAmps similares

Question

Antes de nada, diré que en su día, hace muchos años, hice algunos cursos de EE. Sólo recuerdo un poco.

Estaba simulando un simple amplificador no inversor utilizado en un entorno de CC como repaso y me di cuenta de que dependiendo del modelo de OpAmp que utilizara, obtenía resultados muy diferentes en el simulador.

Estuve comparando las dos hojas de datos y no veo una diferencia significativa.

                           LM324         LF412
Parameter                Min / Max     Min / Max
Input Offset Voltage     ?   / 3mV     ?   / 3mV
Input Bias Current       ?   / 100nA   ?   / 200pA
Input Offset Current         / 30nA       / 100pA
Input Common Voltage     0   / V+-1.5V -11V/ 11V
Supply Current           ?   / 1.2mA       / 6.5mA
Output Source Current    20mA/ ?       ?   / ?

El LM324 y LF412 hojas de datos. Estoy utilizando este resumen para refrescar lo que significan todos estos términos.

El parámetro del que no estoy seguro es el rango de tensión de modo común de entrada.

Creo que, debido a la "aproximación del cortocircuito virtual", ambas entradas (V+, V-) están más o menos a la misma tensión la mayor parte del tiempo. Así que no creo que esto afecte a la simulación, pero no estoy seguro.

Todos los demás parámetros parecen estar dentro del rango de cada uno (o están en el rango pA/nA por lo que los estoy ignorando).

Este es el circuito que estoy probando. Intenta amplificar el Vin por 1,4 de tal manera que cuando Vin está en el rango de 0,5V DC entonces Vout es 1,4 veces mayor en el rango de 0,12V DC (soy consciente de que nunca llegaré a los 12V exactamente).

Aquí está la simulación usando el LM324. Esta es la salida esperada:

Vmax es naranja

Vout es azul

Vin (la entrada V+) es amarilla

Aquí está la simulación utilizando el LF412. Esto parece muy mal:

Vmax es naranja

Vout es azul

Vin (la entrada V+) es púrpura

tambiénVin (la entrada V-) es amarilla

Answer 1

Teoría

simular este circuito - Esquema creado con CircuitLab

La tensión de modo común de entrada es una forma elegante de decir la tensión media de las dos entradas: \begin{gather} V_{cm} = \frac{V_{-} + V_{+}}{2} \end{gather}

Cuando el op-amp funciona con retroalimentación negativa se puede suponer que \$V_{cm} = V_{-} = V_{+}\$ .

La especificación está ahí para decirte que hay un cierto rango de voltajes de entrada que puedes esperar que el op-amp funcione correctamente. Esto es siempre dentro de la alimentación dada al op-amp: \begin{gather} V_{s-}+A \le V_{cm} \le V_{s+}-B \end{gather} donde \$A\$ y \$B\$ son números no negativos y propiedades del op-amp. Por supuesto, en lugar de darte estos dos números directamente te dan una cantidad más útil, que es el rango de tensión de modo común de entrada: \begin{gather} V_{cm-} \le V_{cm} \le V_{cm+} \end{gather} Es necesario que esta condición se cumpla si se quiere esperar que el op-amp funcione correctamente.

Tenga en cuenta que los parámetros \$A\$ y \$B\$ son funciones potencialmente no lineales de la tensión de alimentación (y posiblemente de otros valores como la corriente de salida). Tienes que consultar la hoja de datos para ver cómo cambia el rango de tensión en modo común con la tensión de alimentación.

Por ejemplo, tome el LF412 . En las figuras 4 y 5 muestra la tensión de modo común en función de las tensiones de alimentación positivas y negativas (referenciadas frente a la tensión media de alimentación). Sin embargo, simplemente no se especifica a continuación \$V_{s+} - V_{s-} \le 10V\$ porque presumiblemente el op-amp no funcionará correctamente con menos voltaje.

Ahora volvamos a dibujar el circuito y elijamos un nuevo punto de tierra de forma que obtengamos una alimentación simétrica:

simular este circuito

En su gráfico, está eligiendo \$V_{in} \in [0V, 5V]\$ . Esto corresponde a \$V_{+} \in [-6V, -1V]\$ . Mirando la figura 5 de la hoja de datos del LF412, el mínimo voltaje de modo común permitido para una alimentación negativa de -6V es de aproximadamente -2,9V, o en la referencia no desplazada que estás usando de 3,1V.

TL;DR: El modelo LF412 de PartSim está roto

Aparte de esto, por alguna razón el modelo de Partsim para el LF412 está roto (lo más probable es que los pines estén desordenados). Por suerte, puedes conseguir el archivo del modelo aquí . Tenga en cuenta que necesita un poco de ajuste para que funcione con partsim.

Aquí está el modelo modificado:

*//////////////////////////////////////////////////////////
*LF412 LOW OFFSET, LOW DRIFT DUAL JFET INPUT OP-AMP MODEL
*//////////////////////////////////////////////////////////
*
* connections:  non-inverting input
*               |   inverting input
*               |   |   positive power supply
*               |   |   |   negative power supply
*               |   |   |   |   output
*               |   |   |   |   |
*               |   |   |   |   |
.SUBCKT LF412N  1   2  99  50  28
*
*Features:
*Fast settling time (.01%) =           2uS
*High bandwidth =                     3MHz
*High slew rate =                   10V/uS
*Low offset voltage =                  1mV
*Low supply current =                1.8mA
*NOTE: Model is for single device only and simulated
*      supply current is 1/2 of total device current.
*
IOS 2 1 25.0P
CI1 1 0 3P
CI2 2 0 3P
R1 1 3 1E12
R2 3 2 1E12
I1 99 4 1.0M
J1 5 2 4 JX
J2 6 7 4 JX
R3 5 50 650
R4 6 50 650
*Fp2=28 MHZ
C4 5 6 4.372P
I2 99 50 800UA
EOS 7 1 POLY(1) 16 49 1E-3 1
R8 99 49 80K
R9 49 50 80K
V2 99 8 2.13
D1 9 8 DX
D2 10 9 DX
V3 10 50 2.13
EH 99 98 99 49 1
G1 98 9 5 6 20E-3
R5 98 9 10MEG
VA3 9 11 0
*Fp1=18 HZ
C3 98 11 857.516P
*Fp=30 MHz
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 5.305E-15
G4 98 16 3 49 1E-8
L2 98 17 144.7M
R13 17 16 1K
F6  99 50 VA7 1
F5  99 23 VA8 1
D5  21 23 DX
VA7 99 21 0
D6  23 99 DX
E1  99 26 99 15 1
VA8 26 27 0
R16 27 28 50
V5  28 25 0.646V
D4  25 15 DX
V4  24 28 0.646V
D3  15 24 DX
.MODEL DX D(IS=1E-15)
.MODEL JX PJF(BETA=1.183E-3 VTO=-.65 IS=50E-12)
.ENDS
*$

Aquí están los resultados de la simulación con el modelo fijo ( \$V_{out}\$ es azul, \$V_{+}\$ es negro):

Curiosamente, la salida no se ajusta a la teoría; eso es porque simplemente asumí que, como la figura 5 de la hoja de datos no muestra el rango de tensión de alimentación negativa frente a la tensión en modo común, no funcionará por debajo de eso. En cambio, simplemente no se especifica. El modelo simplemente funciona por debajo de eso, aunque no sé qué comportamiento tendrá en la vida real.

Answer 2

El macromodelo de opampón Boyle estándar que se utiliza para la mayoría de los opamps antiguos no modelar el rango de entrada en modo común.

Sin embargo, el rendimiento de la temperatura, rango de entrada en modo común tensión de compensación, corriente de offset, protección de entrada, rechazo de la fuente de alimentación, ruido, THD, impedancia de entrada, buena resistencia de salida de CA y de la corriente de alimentación frente a la tensión de alimentación son algunos de los los parámetros más importantes que no se modelan con la macro topología de Boyle.

Actualmente, TI sólo da un modelo básico de Boyle para LM324 (y no da nada para el LM324-N). Las cosas se ponen más interesantes para el LF412. Para el estándar bog, también obtener sólo un modelo de Boyle indetificado como "LF412C" dentro del archivo. Pero para el LF412- N usted obtener un modelo (identificado como "LF412/NS" dentro del archivo) que tiene efectos de modo común. Cuidado con el descargador.

Por supuesto no tengo ni idea de lo que usa partsim. El dicho "muéstrame el código" se traduce en "muéstrame el modelo" cuando se trata de simulaciones SPICE de opamps más allá de lo básico.

Pasemos ahora a cuestiones más prácticas. Primero dices:

Se trata de amplificar la tensión Vin por 1,4 de tal manera que cuando Vin está en el rango de 0,5V DC entonces Vout es 1,4x mayor en el rango de 0,12V DC (soy consciente de que nunca llegaré a 12V exactamente).

No es así como va a funcionar, debido a la configuración no inversora, el factor va a ser 2,4 (1+Rf/Rg).

Pero dejando eso de lado, incluso con el modelo LM324 de TI al menos consigues que limite la salida por debajo del raíl de 12V... que es más de lo que consigue partsim:

Aquí está el LF412C, este no puede oscilar hasta el 0:

Y así es como funciona; querrás consultar el esquema de Boyle mientras lees lo que sigue. He rodeado las partes que simulan los límites relacionados con los rieles para la salida.

Para el LM324, las fuentes de tensión en serie con los diodos (que simulan los límites del carril, esto es el más a la derecha se ajustan a

DC    5 53 DX
DE   54  5 DX
VC    3 53 DC 2.100
VE   54  4 DC .6

Así que en el lado de baja va a 0 después de restar la caída del diodo, pero el lado de alta va a unos 10,5V (caída de 2,1 diodos).

Para el LF412C ahora tenemos

VC    3 53 DC 2.200
VE   54  4 DC 2.200

Así que ambos lados (alto y bajo) se limitan a unos 1,6V del carril. Así es como simulan que el LM324 es capaz de funcionar con una sola alimentación, pero el LF412 no.

Tengo que ver ahora qué compra el modelo LF412NS más elegante aquí, si es que hay algo. Bueno, no hay diferencia real

*********OUTPUT VOLTAGE LIMITING********
V2 99 8 2.13
D1 9 8 DX
D2 10 9 DX
V3 10 50 2.13

Todavía tengo que entender qué es lo que hacen realmente las partes del código/declaración sobre el modo común en ese último modelo, pero no parece añadir ninguna limitación obvia del rango de entrada además de lo que ya imponen las limitaciones del swing de salida (como resultado).

---

Creo que he descubierto cuál es la adición en el modelo NS. La hoja de datos del LF412 (incluyendo la variante N) tiene una CMRR típica de 100dB. Eso significa para una tensión de modo común de 5V un cambio en la salida de 50uV. Con el modelo 412NS obtenemos exactamente ese "efecto de modo común". Con el modelo 412C es una cosa/valor aparentemente aleatorio.

Sin embargo, no hay simulación de la entrada en modo común gama en esta última tampoco, parece.