No iba a responder, pero acabo de adquirir un nuevo compilador y también quería mostrar al autor original de la pregunta cómo podía utilizar arrays para facilitarle la vida.
La teoría elemental de los números, tal y como se ha comentado aquí y en el hilo complementario, nos permite eliminar el conjunto $E=\{13,17,19,23,25,27,29,31,32,34,37,38,41,43,44,46,47,49,50,51\}$ y también dicta que los conjuntos $C_{11}=\{11,22,33\}$ , $C_{13}=\{26,39,52\}$ y $C_{16}=\{16,48\}$ están todos en el conjunto de tarjetas en un ensayo exitoso o todos ausentes.
Esto deja el conjunto $F=\{1,2,3,4,5,6,7,8,9,10,12,14,15,18,20,21,24,28,30,35,36,40,42,45\}$ de $24$ libre, o al menos con menos restricciones. Tenemos que incluir al menos uno de los conjuntos restringidos, $C_{11}$ , $C_{12}$ o $C_{16}$ porque no hay suficientes cartas en $F$ . Las sumas de los recíprocos de los elementos de $F$ , $C_{11}$ , $C_{12}$ y $C_{16}$ son $\frac{85}{24}$ , $\frac16$ , $\frac1{12}$ y $\frac1{12}$ respectivamente.
$F\cup C_{16}$ es lo suficientemente grande, pero la suma es $\frac{87}{24}$ demasiado grande. También $F\cup C_{11}$ y $F\cup C_{13}$ suma a $\frac{89}{24}$ y $\frac{87}{24}$ , por lo que incluso si se quita la tarjeta $1$ para llegar a $26$ tarjetas la suma será demasiado grande.
$F\cup C_{11}\cup C_{16}$ sumas a $\frac{91}{24}$ , por lo que tendríamos que eliminar $3$ artículos de $F$ con valor total $\frac{43}{24}$ . Desde $\frac12+\frac13+\frac14=\frac{13}{12}<\frac{43}{24}$ , tarjeta $1$ debe ser eliminado. Además, como $\frac11+\frac13+\frac14=\frac{19}{12}<\frac{43}{24}$ , también tarjeta $2$ debe ser eliminado, pero ahora estamos en $\frac7{24}$ con una sola carta.
$F\cup C_{13}\cup C_{16}$ se elimina de la consideración de manera similar.
$F\cup C_{11}\cup C_{13}$ sumas a $\frac{91}{24}$ también, pero ahora tenemos $4$ tarjetas para trabajar. Una vez más, las consideraciones de magnitud dictan que las tarjetas $1$ y $2$ están destinados a ser eliminados, pero ahora después de hacerlo nos encontramos con que tenemos que llegar a $\frac{91}{24}-2-\frac11-\frac12=\frac7{24}$ en dos tarjetas. Como el denominador es divisible por $8$ una de las otras cartas retiradas debe ser $8$ , $24$ o $40$ . Encontramos que $\frac18+\frac16=\frac1{24}+\frac14=\frac1{40}+\frac4{15}=\frac7{24}$ Así que tenemos dos soluciones:
$\{3,4,5,7,9,10,11,12,14,15,18,20,21,22,24,26,28,30,33,35,36,39,40,42,45,52\}$
y
$\{3,5,6,7,8,9,10,11,12,14,15,18,20,21,22,26,28,30,33,35,36,39,40,42,45,52\}$
Eso deja el conjunto $F\cup C_{11}\cup C_{13}\cup C_{16}$ . Una vez más, las consideraciones de magnitud eliminan la tarjeta $1$ de la consideración por lo que tenemos que encontrar $5$ más tarjetas de $F$ que suman $\frac{31}{8}-2-\frac11=\frac78$ . Ahora bien, la paciencia y la teoría elemental de los números podrían limpiar esto en una hora más o menos a mano, pero eso sería un largo post. En su lugar, ofrezco un programa de fuerza bruta que busca el espacio restante de ${23\choose 5} = 33649$ posibilidades.
Creo matrices para los conjuntos $F$ , $C_{11}$ , $C_{13}$ y $C_{16}$ y luego mantener los recíprocos de las cartas en $F$ . Entonces calculo la suma de los recíprocos de $F\cup C_{11}\cup C_{13}\cup C_{16}-\{1\}$ y restar $2$ para saber cuál es mi objetivo para el próximo $5$ tarjetas que hay que eliminar es. Haz un bucle con todas las posibilidades, contando e imprimiendo todas las soluciones. Como el error de redondeo va a ser menor que $50$ ulps y el mayor error real es $\frac1{2^3\cdot3^2\cdot5\cdot7}=\frac1{2520}$ cortando las posibles soluciones en $100$ ulps separa definitivamente las soluciones verdaderas de las espurias.
El programa imprime $30$ soluciones, por lo que junto con el $2$ obtenido a mano, esto es consistente con los resultados de @Giovanni Resta.
program cards26
implicit none
integer, parameter :: dp = kind([double precision::])
integer i1,i2,i3,i4,i5
integer, parameter :: cards(24) = [1,2,3,4,5,6,7,8,9,10,12,14, &
15,18,20,21,24,28,30,35,36,40,42,45]
integer, parameter :: c11(3) = [11,22,33]
integer, parameter :: c13(3) = [26,39,52]
integer, parameter :: c16(2) = [16,48]
! integer, parameter :: exclude(20) = [13,17,19,23,25,27,29,31, &
! 32,34,37,38,41,43,44,46,47,49,50,51]
real(dp),parameter :: reciprocals(size(cards)) = 1.0_dp/cards
real(dp) x0,x1,x2,x3,x4,x5
integer N
x0 = sum(1.0_dp/cards)+sum(1.0_dp/c11)+sum(1.0_dp/c13)+ &
sum(1.0_dp/c16)-2-1
write(*,*) 'Target = ', x0
N = 0
do i1 = 2,size(cards)-4
x1 = reciprocals(i1)
do i2 = i1+1,size(cards)-3
x2 = x1+reciprocals(i2)
do i3 = i2+1,size(cards)-2
x3 = x2+reciprocals(i3)
do i4 = i3+1,size(cards)-1
x4 = x3+reciprocals(i4)
do i5 = i4+1,size(cards)
x5 = x4+reciprocals(i5)
if(abs(x5-x0) < 100*epsilon(1.0_dp)) then
N = N+1
write(*,'(i4,1x,26(i2,1x),f19.17)') N, &
pack(cards,[(all(cards(N)/=cards([1,i1,i2,i3, &
i4,i5])),N=1,size(cards))]),c11,c13,c16,x5
end if
end do
end do
end do
end do
end do
end program cards26
