Diferentes de etiquetado de permutación representación en la BRECHA

Question

Tengo una permutación $x=(3,4)(5,7)(6,8)(9,12)(10,13)(11,14)$ que actúa sobre el conjunto de [1,2,3...14] puntos y tener otra permutación $x'=(1,4)(5,6)(7,8)...(24,27)$ que actúa sobre el conjunto de los 27 puntos. Quiero multiplicar ambos permutaciones $x$$x'$, pero el uso de etiquetado diferentes, de lo contrario el mismo etiquetado permutaciones será multiplicado por qué no me dan la solución que se requiere.

Mi pregunta es ¿cómo puedo cambiar el etiquetado de las permutaciones en la BRECHA, yo.e si $x$ es una permutación de grado $m$ $x'$ es de permutación de grado $n$ $x*x'$ me dará permutación de grado $m+n$.

¿Cómo puedo hacer esto en la BRECHA?

Answer 1

Usted no puede cambiar eso para reemplazar el construido-en la multiplicación. Pero usted puede buscar en la BRECHA de funciones ListPerm, PermList y otras funciones documentadas en la misma sección del manual. El uso de ellos, usted puede convertir permutaciones de listas, luego modificarlos después de cualquier lógica que es posible que desee aplicar y, a continuación, crear una nueva permutación de que. Por ejemplo,

gap> a:=(3,4)(5,7)(6,8)(9,12)(10,13)(11,14);
(3,4)(5,7)(6,8)(9,12)(10,13)(11,14)
gap> b:=(1,3)(5,4)(7,8)(24,27);
(1,3)(4,5)(7,8)(24,27)
gap> l:=ListPerm(b);
[ 3, 2, 1, 5, 4, 6, 8, 7, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 
  22, 23, 27, 25, 26, 24 ]
gap> n:=LargestMovedPoint(a);
14
gap> m:=l+n;
[ 17, 16, 15, 19, 18, 20, 22, 21, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 
  33, 34, 35, 36, 37, 41, 39, 40, 38 ]
gap> c:=PermList(Concatenation([1..n],m));
(15,17)(18,19)(21,22)(38,41)
gap> a*c;
(3,4)(5,7)(6,8)(9,12)(10,13)(11,14)(15,17)(18,19)(21,22)(38,41)

Si por casualidad usted está pensando acerca de los productos directos de la permutación de grupos, en caso de que otra forma de hacer esto. Observar el siguiente comportamiento:

gap> G:=Group((1,2));
Group([ (1,2) ])
gap> H:=Group((1,2));
Group([ (1,2) ])
gap> DirectProduct(G,H);
Group([ (1,2), (3,4) ])

Actuando puntos del 2º grupo fueron "desplazado" de forma automática. Así, para el mismo permutaciones como el anterior, se puede tener:

gap> a:=(3,4)(5,7)(6,8)(9,12)(10,13)(11,14);
(3,4)(5,7)(6,8)(9,12)(10,13)(11,14)
gap> b:=(1,3)(5,4)(7,8)(24,27);
(1,3)(4,5)(7,8)(24,27)
gap> G:=Group(a);
Group([ (3,4)(5,7)(6,8)(9,12)(10,13)(11,14) ])
gap> H:=Group(b);
Group([ (1,3)(4,5)(7,8)(24,27) ])
gap> D:=DirectProduct(G,H);
Group([ (1,2)(3,5)(4,6)(7,10)(8,11)(9,12), (13,14)(15,16)(17,18)(19,20) ])
gap> f1:=Embedding(D,1);
1st embedding into Group([ (1,2)(3,5)(4,6)(7,10)(8,11)(9,12), (13,14)(15,16)
(17,18)(19,20) ])
gap> f2:=Embedding(D,2);
2nd embedding into Group([ (1,2)(3,5)(4,6)(7,10)(8,11)(9,12), (13,14)(15,16)
(17,18)(19,20) ])
gap> c:=a^f1*b^f2;
(1,2)(3,5)(4,6)(7,10)(8,11)(9,12)(13,14)(15,16)(17,18)(19,20)

Tenga en cuenta que la respuesta es diferente de la de mi ejemplo anterior, ya que la BRECHA recogido más eficiente de permutación de representación para el producto directo de dos grupos, actuando sólo sobre 20 puntos. Si usted va a construir un producto directo de la $S_{14}$$S_{27}$, actuará en 4 puntos y el resultado de la permutación será exactamente el mismo que en el primer ejemplo:

gap> S14:=SymmetricGroup(14);
Sym( [ 1 .. 14 ] )
gap> S27:=SymmetricGroup(27);
Sym( [ 1 .. 27 ] )
gap> D:=DirectProduct(S14,S27);
<permutation group of size 949273031787355066495581919641600000000 with 4 gen\
erators>
gap> f1:=Embedding(D,1);
1st embedding into <permutation group of size 9492730317873550664955819196416\
00000000 with 4 generators>
gap> f2:=Embedding(D,2);
2nd embedding into <permutation group of size 9492730317873550664955819196416\
00000000 with 4 generators>
gap> c:=a^f1*b^f2;
(3,4)(5,7)(6,8)(9,12)(10,13)(11,14)(15,17)(18,19)(21,22)(38,41)

Supongo que en tu caso G y H serán algunos de los grupos más grandes, donde se tomará a y b , no cíclico con a y b como generadores, pero que no necesitan estar lleno grupos simétricos. También, puede ser vale la pena experimentar el enfoque que le demuestran un mejor rendimiento.

Espero que esto ayude!