¿Qué es la serie Puiseux de la función Bessel$J_n(n)$?

Question

Por la experimentación numérica puedo encontrar los tres primeros términos de la serie de Puiseux de la función de Bessel de primera especie

$$ J_n(n) = \frac{\Gamma(\frac13)}{2^{2/3}\cdot 3^{1/6} \cdot \pi}n^{-1/3} - \frac{1}{35\cdot 6^{1/3}\cdot\Gamma(\frac13)}n^{-5/3} - \frac{\Gamma(\frac13)}{225 \cdot 2^{2/3}\cdot 3^{1/6}\cdot \pi}n^{-7/3} +\mathcal{S}(n^{-11/3}) $$

How does this series continue?

See also this application.

How I got this far

first term

For the first term, start with the integral representation

$$ J_n(n) = \frac{1}{2\pi}\int_{-\pi}^{\pi} d\theta \cos[n(\sin(\theta)-\theta)] $$

For $n\to\infty$ the only significant contributions to this integral come from values of $\theta$ that are close to zero. Therefore we approximate $\sin(\theta)-\theta\aprox-\theta^3/6$ and find

$$ \lim_{n\to\infty} n^{1/3}\cdot\frac{1}{2\pi}\int_{-\pi}^{\pi} d\theta \cos[-n\theta^3/6] = \frac{\Gamma(\frac13)}{2^{2/3}\cdot3^{1/6}\cdot\pi} $$

En Mathematica:

Limit[1/(2π) Integrate[Cos[n (-(θ^3/6))], {θ, -π, π}]*n^(1/3), n -> ∞]

Gamma[1/3]/(2^(2/3) 3^(1/6) π)

segundo plazo

En Mathematica, definir la función de Bessel y su plazo de aproximación, así como su diferencia numérica evaluado a 1000 dígitos:

b[n_] = BesselJ[n, n];
ba[n_] = Gamma[1/3]/(2^(2/3)*3^(1/6)*π)*n^(-1/3);
B[n_] := N[b[n] - ba[n], 10^3]

Cómo calcular la diferencia numérica se comporta grandes $n$ (después de multiplicar por $n^{5/3}$):

ListLinePlot[T = Table[B[n]*n^(5/3), {n, 10^Range[2, 5, 1/4]}]]

y encontrar el valor numérico aproximado del límite de $n\to\infty$:

NumericalMath`NSequenceLimit[T]

-0.00586928848357833870

A continuación, utilice AskConstants a encontrar que este número es probablemente igual a $-\frac{1}{35\cdot 6^{1/3}\cdot\Gamma(\frac13)}$.

tercer término

Mismo procedimiento que en el segundo período, pero con la mejor aproximación

ba[n_] = Gamma[1/3]/(2^(2/3)*3^(1/6)*π)*n^(-1/3) -
           1/(35*6^(1/3)*Gamma[1/3])*n^(-5/3);

y multiplicando la diferencia B[n] por $n^{7/3}$ antes de tomar el límite numérico $n\to\infty$. El resultado es $-0.0019880325262065435671$, que AskConstants piensa que es igual a $- \frac{\Gamma(\frac13)}{225 \cdot 2^{2/3}\cdot 3^{1/6}\cdot \pi}$.

de orden superior en términos

La receta anterior se puede continuar el más alto en términos de orden, pero lo he perdido la confianza en las capacidades de AskConstants. El cuarto término es $+0.00048679979012516409164$, que puede ser

$$ +\frac{1213}{511875\cdot6^{1/3}\cdot \Gamma(\frac13)}n^{-11/3} $$

pero tan grandes racionales no inspiran confianza.

Answer 1

La respuesta es dada por Ernst Meissel en este 1891 papel (en alemán):

$$ J_n(n) = \frac{1}{\pi} \sum_{m=0}^{\infty} \lambda_m \cdot \Gamma\left(\frac{2m+4}{3}\right) \cdot \left(\frac{6}{n}\right)^{\frac{2m+1}{3}} \cdot \cos\left(\frac{2m+1}{6}\pi\right) $$

The coefficients $\lambda_m$ describe the Taylor series of the solution $u(x)=\sum_{m=0}^{\infty} \lambda_m x^{2m+1}$ of the transcendental equation $u-\sin(u)=x^3/6$ around $x=0$. Term-by-term comparison gives

$$ \lambda_0=1\\ \lambda_1=\frac{1}{60}\\ \lambda_2=\frac{1}{1400}\\ \lambda_3=\frac{1}{25200}\\ \lambda_4=\frac{43}{17248000}\\ \lambda_5=\frac{1213}{7207200000}\\ \lambda_6=\frac{151439}{12713500800000}\\ \lambda_7=\frac{33227}{38118080000000}\\ \lambda_8=\frac{16542537833}{252957982717440000000}\\ \lambda_9=\frac{887278009}{177399104762880000000}\\ \lambda_{10}=\frac{15233801224559}{39217856135377920000000000}\\ \ldots $$

These coefficients can be calculated efficiently with the Mathematica code

λ[0] = 1;
λ[m_Integer /; m >= 1] := λ[m] = Module[{Λ, u, x},
  u = Sum[λ[j] x^(2 j + 1), {j, 0, m - 1}] + Λ x^(2 m + 1);
  Λ /. First[Solve[SeriesCoefficient[u - Sin[u], {x, 0, 2 m + 3}] == 0, Λ]]]

Or all at once by series inversion (thanks to J.M.): calculate $\lambda_0\ldots\lambda_n$ con

With[{n = 5},
  ComposeSeries[InverseSeries[Series[u-Sin[u], {u,0,2n+3}]], x^3/6 + O[x]^(2n+5)]]

$$ x+\frac{x^3}{60}+\frac{x^5}{1400}+\frac{x^7}{25200}+\frac{43 x^9}{17248000}+\frac{1213x^{11}}{7207200000}+\mathcal{S}(x^{12}) $$

Gracias a J. M. quien señaló Meissel del papel para mí.