Tengo un grupo de Biblioteca para grupos pequeños y quiero encontrar su presentación utilizando GAP.
He intentado utilizar PresentaciónFpGroup(G) pero fracasó.
Por favor, sugiérame un método.
Respuesta
¿Demasiados anuncios?
Resumen.
Si G es el grupo para el que quieres una presentación, utiliza primero
H:=Image(IsomorphismFpGroup(G));para transformar G en un tipo de FPGroup. GAP dará salida a los generadores. A continuación, siga con
RelatorsOfFpGroup(H);para ver las relaciones.
Observación.
A veces puede ser útil llamar a SimplifiedFpGroup como aquí:
H:=SimplifiedFpGroup(Image(IsomorphismFpGroup(G))); para obtener una presentación de forma más sencilla.
Ejemplo.
El siguiente ejemplo lo demuestra para el grupo diedro de orden 256. Primero averiguaremos su ID y lo extraeremos de la Biblioteca de Grupos Pequeños:
gap> D:=DihedralGroup(256);
<pc group of size 256 with 8 generators>
gap> IdGroup(D);
[ 256, 539 ]
gap> G:=SmallGroup(256,539);
<pc group of size 256 with 8 generators>Está dada por una presentación de tipo especial, llamada presentación policíclica . Esto es muy eficiente para procesar este grupo en un ordenador, pero no es muy eficiente para el procesamiento por los seres humanos:
gap> H:=Image(IsomorphismFpGroup(G));
<fp group of size 256 on the generators [ F1, F2, F3, F4, F5, F6, F7, F8 ]>
gap> RelatorsOfFpGroup(H);
[ F1^2, F2^-1*F1^-1*F2*F1*F3^-1, F3^-1*F1^-1*F3*F1*F4^-1, F4^-1*F1^-1*F4*F1*F5^-1,
F5^-1*F1^-1*F5*F1*F6^-1, F6^-1*F1^-1*F6*F1*F7^-1, F7^-1*F1^-1*F7*F1*F8^-1,
F8^-1*F1^-1*F8*F1, F2^2, F3^-1*F2^-1*F3*F2*F4^-1, F4^-1*F2^-1*F4*F2*F5^-1,
F5^-1*F2^-1*F5*F2*F6^-1, F6^-1*F2^-1*F6*F2*F7^-1, F7^-1*F2^-1*F7*F2*F8^-1,
F8^-1*F2^-1*F8*F2, F3^2*F5^-1*F4^-1, F4^-1*F3^-1*F4*F3, F5^-1*F3^-1*F5*F3,
F6^-1*F3^-1*F6*F3, F7^-1*F3^-1*F7*F3, F8^-1*F3^-1*F8*F3, F4^2*F6^-1*F5^-1,
F5^-1*F4^-1*F5*F4, F6^-1*F4^-1*F6*F4, F7^-1*F4^-1*F7*F4, F8^-1*F4^-1*F8*F4,
F5^2*F7^-1*F6^-1, F6^-1*F5^-1*F6*F5, F7^-1*F5^-1*F7*F5, F8^-1*F5^-1*F8*F5,
F6^2*F8^-1*F7^-1, F7^-1*F6^-1*F7*F6, F8^-1*F6^-1*F8*F6, F7^2*F8^-1, F8^-1*F7^-1*F8*F7,
F8^2 ]Por suerte, en este caso SimplifiedFpGroup produce una presentación mucho más corta:
gap> K:=SimplifiedFpGroup(H);
<fp group on the generators [ F1, F2 ]>
gap> RelatorsOfFpGroup(K);
[ F1^2, F2^2, (F1*F2)^128 ]Sólo para demostrar que estos tres grupos son isomorfos,
gap> List([G,H,K],StructureDescription);
[ "D256", "D256", "D256" ]Tenga en cuenta que si la conexión con el grupo original es importante, la operación IsomorphismSimplifiedFpGroup debe utilizarse en lugar de SimplifiedFpGroup . Además, si para algún grupo concreto la presentación resultante no es satisfactoria, se podría intentar un uso interactivo más sofisticado de los comandos de transformación de Tietze disponibles en GAP (véase aquí ).
