Es el ideal de la $J:=\langle -y^2+xz,x^5-z^3 \rangle$ prime en $\Bbb{C}[x,y,z]?$

Question

Queremos demostrar que el ideal de $J:=\langle -y^2+xz,x^5-z^3 \rangle$ es el primer en $\Bbb{C}[x,y,z].$

Mi intento. Informal de un pensamiento es tomar las ecuaciones $y^2-xz=0,\ x^5-z^3=0 \iff y^2=xz,\ x^5=z^3.$ a partir De esto podemos establecer $x=t^3,y=t^4,z=t^5.$

Así que, ahora vamos a definir la asignación de $$\phi: \Bbb{C}[x,y,z]\longrightarrow \Bbb{C}[t^3,t^4,t^5],\\ f(x,y,z)\mapsto \phi(f(x,y,z)):=f(t^3,t^4,t^5).$$

No es difícil ver que $\phi$ es un epimorphism con la imagen de $\mathrm{Im}\phi=\Bbb C[t^3,t^4,t^5].$$J\subseteq \ker\phi$.

Preguntas.

1) ¿Qué acerca de la $\ker \phi \subseteq J$? Una idea es tomar el algoritmo de la división, y de esta a la afirmación de que si $f\in \ker \phi\implies f=(-y^2+xz)\cdot q_1+r_1$$r_1\in \ker\phi,\ f= (x^5-z^3)\cdot q_2+r_2$$r_2\in \ker\phi$. Pero esto podría ayudar?

2) Si $J=\ker\phi,$ (a partir del 1er Teorema de Isomorfismo) $$\Bbb C[x,y,z]/\langle -y^2+xz,x^5-z^3 \rangle \cong \Bbb C[t^3,t^4,t^5] \subset \Bbb C [t],$$

así, $$\begin{equation} \begin{split}\Bbb C [t] \text{ is an integral domain }& \implies \Bbb C[t^3,t^4,t^5] \text{ is an integral domain } \\ & \iff \Bbb C[x,y,z]/\langle -y^2+xz,x^5-z^3\rangle \text{ is an integral domain} \\ & \iff J \text{ is prime ideal }. \end{split}\end{equation}$$ Es esta la reivindicación del derecho?

3) ¿hay alguna alternativa pruebas de 1) y 2) ?

Gracias de antemano.

Answer 1

Tenga en cuenta que $J$ no es un alojamiento ideal, ya $x^4-y^3,x^4+y^3\notin J$, pero que $$(x^4-y^3)(x^4+y^3)=x^8-y^6=x^3(x^5-z^3)+(x^2z^2+xy^2z+y^4)(xz-y^2)\in J.$$

Answer 2

Tenga en cuenta que la salvia no confirme la primalidad de un determinado ideal.

sage: R.<x,y,z> = PolynomialRing(QQ)
sage: J = R.ideal( [ -y^2 + x*z, x^5 - z^3 ] )
sage: J
Ideal (-y^2 + x*z, x^5 - z^3) of Multivariate Polynomial Ring in x, y, z over Rational Field
sage: J.is_prime()
False
sage: J.primary_decomposition()
[Ideal (y^2 - x*z, x^2*y + z^2, x^3 + y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field,
 Ideal (y^2 - x*z, x^2*y - z^2, x^3 - y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field]
sage: J.primary_decomposition_complete()
[(Ideal (y^2 - x*z, x^2*y + z^2, x^3 + y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field,
  Ideal (y^2 - x*z, x^2*y + z^2, x^3 + y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field),
 (Ideal (y^2 - x*z, x^2*y - z^2, x^3 - y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field, 
  Ideal (y^2 - x*z, x^2*y - z^2, x^3 - y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field)
  ]

(El último resultado fue ajustado manualmente.)

---

Después de editar: Para obtener algunos contraejemplos utilizamos el hecho de que $$ J = P\cap Q\ ,$$ donde $P,Q$ están por encima de la primer ideales ofrecidos por sage: $$ \begin{aligned} P &=\langle\ y^{2} - x z,\ x^{2} y + z^{2},\ x^{3} + y z\ \rangle\ ,\\ Q &=\langle\ y^{2} - x z,\ x^{2} y - z^{2},\ x^{3} - y z\ \rangle\ . \end{aligned} $$ El siguiente código comprueba esta situación.

sage: P, Q = J.primary_decomposition()
sage: P.intersection(Q) == J
True
sage: P.is_prime(), Q.is_prime()
(True, True)
sage: P.gens(), Q.gens()
([y^2 - x*z, x^2*y + z^2, x^3 + y*z], [y^2 - x*z, x^2*y - z^2, x^3 - y*z])

Ahora vamos a hacer la siguiente elección de elementos en el polinomio anillo: $$ \begin{aligned} p &= x^{2} y + z^{2}\in P\ ,\\ q &= x^{2} y - z^{2}\in Q\ ,\\ &\qquad\text{ so the product %#%#% is in both %#%#% and %#%#%, i.e.}\\ pq&\in P\cap Q=J\ . \end{aligned} $$ Esta información se carece de un humano "argumento", pero tenemos más cerca:

sage: p, q = x^2*y + z^2, x^2*y - z^2
sage: p in P, q in Q
(True, True)
sage: p*q in J, p in J, q in J
(True, False, False)

sage: (p*q).lift(J)
[-x^4, z]
sage: p*q == -x^4*(-y^2 + x*z) + z*(x^5 - z^3)
True

Este es el contraejemplo, sage nos dio también la "elevación" de $pq$ en términos de los generadores de $P$, y ahora tenemos que mostrar "humanamente" que $Q$$pq$. Así que asumir que no sería una representación $$ x^2y\pm z^2 =S(-y^2+xz)+T(x^5-z^3)\ . $$ Entonces es imposible para producir $J$ utilizando el monomials $p\not \in J$ (multiplicado por algunos otros monomials). Contradicción. La suposición es falsa.

---

Nota: En mis respuestas, yo siempre trato de entregar todos los detalles que había que conduce a la solución final. De lo anterior, se puede extraer el simple argumento de que en algunas líneas, pero "el trabajo en el ring" es más importante y completo de la experiencia puede mostrar fructífera la próxima vez.