Simplifique $\Gamma\left(\frac27\right) \Gamma\left(\frac{11}{42}\right)/\;\Gamma\left(\frac1{21}\right)$ a términos elementales

Question

¿Cómo podemos demostrar la siguiente identidad? $$\large \frac{\Gamma\left(\frac27\right) \Gamma\left(\frac{11}{42}\right)}{\Gamma\left(\frac1{21}\right)} = \frac{8 \sin\left(\frac\pi7\right) \sqrt{\pi \, \sin\left(\frac\pi{21}\right) \sin\left(\frac{4\pi}{21}\right) \sin\left(\frac{5\pi}{21}\right)}}{\sqrt[42]2 \; \sqrt[3]7 \; \sqrt[28]{19683}}$$ Supongo que podríamos usar el Fórmula de multiplicación de Gauss Pero, ¿cómo?

Answer 1

El producto dado por OP sí puede expresarse elementalmente. Daré una prueba de procedimiento.

Voy a escribir $x\sim y$ si $x/y$ es un producto de números algebraicos y una potencia racional de $\pi$ . Las siguientes son propiedades famosas de la función gamma: $$\tag{1}\Gamma(x) \Gamma(1-x) \sim 1 $$ $$\tag{2}\Gamma(x) \Gamma(x + \frac{1}{2}) \sim \Gamma(2x)$$ $$\tag{3}\Gamma(x) \Gamma(x + \frac{1}{3}) \Gamma(x + \frac{2}{3}) \sim \Gamma(3x)$$ $$\tag{4}\Gamma(x) \Gamma(x + \frac{1}{7}) \cdots \Gamma(x + \frac{6}{7}) \sim \Gamma(7x)$$ La primera es una fórmula de reflexión, las otras son casos de teoremas de multiplicación.

---

Omitiré el $\Gamma$ signo, en primer lugar, utilice $(2)$ en $11/42$ : $$C:=\frac{{\left( {\frac{2}{7}} \right)\left( {\frac{{11}}{{42}}} \right)}}{{\left( {\frac{1}{{21}}} \right)}} \sim \frac{{\left( {\frac{2}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)}} \tag{*}$$ Utilice $(3)$ en $2/7$ con $x=2/21$ : $$C \sim \frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{16}}{{21}}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)}} =\frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)}}$$ Utilice $(4)$ en $1/21$ con $x=1/21$ : $$C\sim \frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)}} \sim \frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{3}} \right)}}\left( {\frac{4}{{21}}} \right)\left( {\frac{7}{{21}}} \right)\left( {\frac{{10}}{{21}}} \right)\left( {\frac{{13}}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)\left( {\frac{{19}}{{21}}} \right)$$ Tenga en cuenta que $1/3$ en el denominador se cancela con $7/21$ en el numerador, algunos términos se anulan entre sí mediante la fórmula de reflexión, dejando $$C \sim \left( {\frac{3}{7}} \right)\left( {\frac{4}{{21}}} \right)\left( {\frac{{13}}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right) $$ Utilice $(3)$ en $4/21$ y $13/21$ : $$C \sim \left( {\frac{3}{7}} \right)\frac{{\left( {\frac{4}{7}} \right)}}{{\left( {\frac{{11}}{21}} \right)\left( {\frac{6}{7}} \right)}}\frac{{\left( {\frac{{13}}{7}} \right)}}{{\left( {\frac{{20}}{{21}}} \right)\left( {\frac{9}{7}} \right)}}\left( {\frac{{16}}{{21}}} \right) \sim \frac{1}{{\left( {\frac{{11}}{{21}}} \right)}}\frac{1}{{\left( {\frac{{20}}{{21}}} \right)\left( {\frac{2}{7}} \right)}}\left( {\frac{{16}}{{21}}} \right)$$ Por último, utilice la fórmula de reflexión para hacer $20/21$ en el numerador da $$C \sim \frac{{\left( {\frac{1}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)}}{{\left( {\frac{2}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}$$ Compara esto con $(\ast)$ da $C \sim \frac{1}{C} $ Por lo tanto $C$ puede expresarse como producto de números algebraicos y una potencia racional de $\pi$ . Tenga en cuenta que $C \sim 1/C$ explica por qué la raíz cuadrada aparece sobre los términos del seno del resultado.

Lo que es esta constante se puede averiguar realizando los pasos anteriores, espero que alguien con más resistencia computacional que yo pueda averiguarlo explícitamente.

Answer 2

Estoy escribiendo un libro (informal) sobre sagemath En el caso de que el problema no se solucione con la ayuda de un ordenador, este post era una ocasión ideal para utilizar Sage de una manera natural y no trivial, aquí estoy copiando y pegando la prueba completa (asistida por ordenador, rápida), para que en situaciones similares uno tenga una línea recta a la solución.

---

Es práctico, y facilita la escritura al utilizar una mejor notación para $\Gamma(k/42)$ para todos los valores potencialmente relevantes de $k$ Así que pongamos formalmente $$ \color{red}{ [k] = \Gamma\left(\frac k{42}\right) }\ ,\qquad k=1,2,\dots, 20,21, 22, \dots, 41,\dots\ \ . $$ Entonces una fórmula de duplicación es $$ [k]\;[k+21]=\text{(Known constant)}\cdot[2k]\ , $$ Nota: En la sección de programación consideramos el puramente multiplicativo ecuaciones funcionales (EF), que son las EF de multiplicación de Gauss, y las EF de reflexión, escritas de forma aditiva, entonces se utiliza notativamente $x_k$ en lugar de $[k]$ (en el mundo aditivo), y la relación anterior se lee $x_k+x_{k+21}-x_{2k}$ es "conocido", esto conduce a un sistema de ecuaciones lineales, y para nuestros propósitos es suficiente pasar a la versión homogénea y buscar una escritura de $x_{11}+x_{12}-x_2$ en términos de las ecuaciones recogidas.

---

Sage nos lleva directamente al final, y sugiere entonces (código en la secuela) mirar las relaciones:

$$ \begin{aligned}{} [4] \cdot[4+6] \cdot[4+12] \cdot[4+18] \cdot[4+24] \cdot[4+30] \cdot[4+36] \cdot[7\cdot 4]^{-1} &=(2\pi)^{6/2}\cdot 7^{1/2-7\cdot 4/42} &&\text{ to power $+1$}\ , \\ % [6] \cdot\color{magenta}{[6+6]} \cdot[6+12] \cdot[6+18] \cdot[6+24] \cdot[6+30] \cdot[6+36] \cdot[7\cdot 6]^{-1} &=(2\pi)^{6/2}\cdot 7^{1/2-7\cdot 6/42} &&\text{ to power $+1$}\ , \\[3mm] % \color{blue}{[2]} \cdot[2+14] \cdot[2+28] \cdot[3\cdot 2]^{-1} &=(2\pi)^{2/2}\cdot 3^{1/2-3\cdot 2/42} &&\text{ to power $-1$}\ , \\ % [4] \cdot[4+14] \cdot[4+28] \cdot\color{magenta}{[3\cdot 4]^{-1}} &=(2\pi)^{2/2}\cdot 3^{1/2-3\cdot 4/42} &&\text{ to power $-1$}\ , \\ % [8] \cdot[8+14] \cdot[8+28] \cdot[3\cdot 8]^{-1} &=(2\pi)^{2/2}\cdot 3^{1/2-3\cdot 8/42} &&\text{ to power $+1$}\ , \\[3mm] % \color{red}{[11]} \cdot[11+21] \cdot[2\cdot 11]^{-1} &=(2\pi)^{1/2}\cdot 2^{1/2-2\cdot 11/42} &&\text{ to power $+2$}\ , \\[3mm] % \color{blue}{[2]} \cdot[42-2] &=\pi\cdot \left(\sin\frac{2\pi}{42}\right)^{-1} &&\text{ to power $-1$}\ , \\ % [6] \cdot[42-6] &=\pi\cdot \left(\sin\frac{6\pi}{42}\right)^{-1} &&\text{ to power $-2$}\ , \\ % [8] \cdot[42-8] &=\pi\cdot \left(\sin\frac{8\pi}{42}\right)^{-1} &&\text{ to power $-1$}\ , \\ % [10] \cdot[42-10] &=\pi\cdot \left(\sin\frac{10\pi}{42}\right)^{-1} &&\text{ to power $-1$}\ . % \end{aligned} $$ Multiplicamos las ecuaciones anteriores, llevadas a las potencias mencionadas, sólo sobreviven los factores coloreados: $$ \begin{aligned} \color{red}{[11]^2} \cdot \color{magenta}{[12]^2} \cdot \color{blue}{[2]^{-2}} &= (2\pi)^6 \cdot \pi^{-5} \cdot 2^{1-22/21} \cdot 3^{-1/2-1/7} \cdot 7^{-2/3} \cdot \\ &\qquad\qquad\cdot \sin^2\frac{6\pi}{42} \cdot \sin\frac{2\pi}{42} \cdot \sin\frac{8\pi}{42} \cdot \sin\frac{10\pi}{42} \end{aligned} $$ que es nuestra relación. Se puede separar el número algebraico, y reescribir poniendo en evidencia $ \color{red}{\frac{11}{42}} + \color{magenta}{\frac{12}{42}} = \color{blue}{\frac{2}{42}} + \color{green}{\frac{21}{42}} $ : $$ \begin{aligned} \frac { \color{red}{\Gamma\left(\frac{11}{42}\right)} \color{magenta}{\Gamma\left(\frac{12}{42}\right)} } { \color{blue}{\Gamma\left(\frac{2}{42}\right)} \color{green}{\Gamma\left(\frac{21}{42}\right)} } &= \frac {\displaystyle 2^3\cdot\sin\frac{\pi}7 \sqrt{ \sin\frac{\pi}{21} \cdot \sin\frac{4\pi}{21} \cdot \sin\frac{5\pi}{21}} } {\displaystyle2^{1/42}\cdot 3^{9/28}\cdot 7^{1/3}} \\ &= \frac {\displaystyle 2^{5/4} (5-\sqrt{21})^{1/4} \sin\frac{\pi}7 } {\displaystyle 2^{1/42}\cdot 3^{9/28}\cdot 7^{1/3}} \ . \end{aligned} $$ Eso es todo.

$\square$

---

Como se prometió, algunos trabajos de arte por ordenador apoyan lo anterior.

---

• (1)

Comprobación numérica de las igualdades anteriores:

LHS = gamma(11/42) * gamma(12/42) / gamma(2/42) / gamma(21/42)
RHS1 = 8 * sin(pi/7) * sqrt(prod([sin(k*pi/21) for k in [1,4,5]])) / 2^(1/42) / 3^(9/28) / 7^(1/3)
RHS2 = 2^(5/4) * sin(pi/7) * (5-sqrt(21))^(1/4) / 2^(1/42) / 3^(9/28) / 7^(1/3)

print "LHS =", LHS.n()
print "RHS1 =", RHS1.n()
print "RHS2 =", RHS2.n()

que da

LHS = 0.299625085598959
RHS1 = 0.299625085598959
RHS2 = 0.299625085598959

• (2)

Polinomio mínimo de la expresión (producto seno) bajo la raíz cuadrada:

K.<u> = CyclotomicField(84)        # 84 = 7*4*3
u42, u21, u4 = u^2, u^4, u^21
s1 = (u42^1 - 1/u42^1) / 2 / u4    # sine of 2.1pi/42 =  pi/21
s4 = (u42^4 - 1/u42^4) / 2 / u4    # sine of 2.4pi/42 = 4pi/21
s5 = (u42^5 - 1/u42^5) / 2 / u4    # sine of 2.5pi/42 = 5pi/21
print (8*s1*s4*s5).minpoly()

lo que da, de forma inmediata, el factor $(5-\sqrt{21})$ :

x^4 - 5*x^2 + 1

• (3)

Como se prometió, el código que encontró la relación "lineal" necesaria para ser utilizado:

R = PolynomialRing(QQ, 'x', 42 )     # quick init, we do not use x0
v = R.gens()
for k in range(42):
    exec('x%s = v[%s]' % (k, k) )    # so x1 is indeed x1, x2 is indeed x2...

def normalized_variable(k):
    return v[ k % 42 ]

def eq(times, k):
    """times should divide 42 in the caller, Gauss FE linearized, no constant."""
    inc = ZZ(42/times)
    return ( sum([ normalized_variable(k + j*inc)
                   for j in range(times) ])
             - normalized_variable(times*k) )

equations = (
    [ eq(times, k)
      for times in [7, 3, 2] # ZZ(42).divisors()[ ::-1 ]
      for k in [ 1..ZZ(42/times) ]
      if  times > 1
      # and ( times != 7 or k == 1 )
    ]
    +
    [ v[k] + v[42-k] for k in [1..21]
      if k in [2, 6, 8, 10] ]
    # last is a psychological condition, knowing the result,
    # exactly this condition makes us go straightforward to the result,  
    # else we have a hard work in the cyclotomic field of all sine values,
    # which is harder than parking the gamma values in each other...
)

J = R.ideal(equations)
f = (x11 + x12 - x2)

print "Is f = %s in J? %s" % ( f, f in J )
lif = f.lift(J)

for r in range(len(equations)):
    if lif[r]:
        print '%+4s TIMES %s' % (lif[r], equations[r])

Lo anterior da:

Is f = -x2 + x11 + x12 in J? True

 1/2 TIMES x4 + x10 + x16 + x22 + x34 + x40
 1/2 TIMES x6 + x12 + x18 + x24 + x30 + x36
-1/2 TIMES x2 - x6 + x16 + x30
-1/2 TIMES x4 - x12 + x18 + x32
 1/2 TIMES x8 + x22 - x24 + x36
   1 TIMES x11 - x22 + x32
-1/2 TIMES x2 + x40
  -1 TIMES x6 + x36
-1/2 TIMES x8 + x34
-1/2 TIMES x10 + x32
sage: 

que "es" la solución.

Answer 3

Parece algo (en particular, los términos de la raíz del denominador del lado derecho) que se obtendría a partir de una constante especial que implique series hipergeométricas. A veces los productos de las funciones gamma aparecen como constantes especiales que surgen en las series de funciones theta (las funciones theta de Ramanujan, por ejemplo). ¿Ha visto este artículo ? Puede que le dé algunas pistas para encontrar productos de valores afines.

Otra posibilidad para relacionar los productos de la función gamma con los valores de la función trigonométrica que se ven en el lado derecho de su identidad sería comprobar los valores trigonométricos especiales que dan, respectivamente, $2/7$ , $11/42$ y $1/21$ , como es $\sin(\vartheta) = \frac{11}{42}$ ¿para algún valor especial? Esto le permitiría obtener algunas constantes especiales de la fórmula del producto de Weierstrass para la función gamma (véase aquí ).

¿Dónde encontró esta identidad para empezar?